home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
pc
/
LOGIC Apple II 5.25" Library - DOS Part 2
/
DOS027.dsk
/
IMPROVED BREAKOUT.int
< prev
next >
Wrap
Text File
|
2012-02-16
|
4KB
|
62 lines
0 GOTO 3005
50 Q=((255-PDL (0))-20)/6:IF Q<0 THEN Q=0:IF Q>38-LL THEN Q=39-LL:COLOR= D:VLIN Q,Q+LL AT 0
55 COLOR= A:IF P>Q THEN 1100:IF Q THEN VLIN 0,Q-1 AT 0:P=Q:RETURN
100 J=Y+W:IF J>=0 AND J<120 THEN 105:W=-W:J=Y:FOR I=1 TO 6:K= PEEK (-16336):NEXT I
105 IF ABS (V)<2 OR NOT VV THEN 110
107 GOSUB 50
110 I=X+V:IF I<0 THEN 1200:GOSUB 50:COLOR= A:K=J/3:IF I>39 THEN 130:IF SCRN(I,K)=A THEN 150:IF I THEN 180:N=N+1
111 V=(N>H)+1:W=(K-P)*2-LL:M=1:IF LL<5 THEN W=W*2:VV=N<OD:IF W=0 AND RND (2) THEN W=1:IF W=0 THEN W=-1:IF LL=0 THEN W= RND (2)-1
120 Z= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336):GOTO 150
121 END
130 FOR I=1 TO 6:M= PEEK (-16336):NEXT I:I=X:M=0
140 V=-V
150 PLOT X,Y/3:COLOR= F:PLOT I,K:X=I:Y=J:GOTO 100
160 PRINT "INVALID. REENTER";
170 INPUT " COLOR (0 TO 15)",E$:IF LEN(E$)=0 THEN RETURN :GOSUB 2000:IF E<0 OR E>15 THEN 160:RETURN
180 IF M THEN V=ABS (V):VLIN K/2*2,K/2*2+1 AT I:S=S+I/2-9:VTAB 21:TAB 13:PRINT S
190 Q= PEEK (-16336)- PEEK (-16336)+ PEEK (-16366)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
200 IF S<720 THEN 140
500 PRINT "CONGRATULATIONS, ";A$;" YOU WIN!":IF LL=0 THEN PRINT "YOU MAY AS WELL RETIRE, CHAMP"
503 IF LL>0 THEN PRINT "HOW ABOUT TRYING A PADDLE LENGTH OF ";LL;"?"
505 A$="CHAMP":GOTO 600
510 PRINT "YOUR SCORE OF ";S;" IS ";:IF S<6 THEN 515
511 IF S<20 THEN 520:IF S<60 THEN 530:IF S<120 THEN 540:IF S<200 THEN 550:IF S<300 THEN 560:IF S<420 THEN 570:IF S<650 THEN 580:GOTO 590
515 PRINT "ROTTEN, YOU TURKEY!":GOTO 600
520 PRINT "TERRIBLE!":GOTO 600
530 PRINT "FAIR. ":GOTO 600
540 PRINT "NOT BAD. ":GOTO 600
550 PRINT "GOOD.":GOTO 600
560 PRINT "VERY GOOD.":GOTO 600
570 PRINT "VERY ,VERY GOOD.":GOTO 600
580 PRINT "EXCELLENT.":GOTO 600
590 PRINT "NEARLY PERFECT.":GOTO 600
600 PRINT "SAME COLORS, ";A$;:GOTO 3030
1100 IF P=Q THEN RETURN :IF Q#39-LL THEN VLIN Q+LL+1,39 AT 0:P=Q:RETURN
1200 FOR I=1 TO 80:Q= PEEK (-16336):NEXT I:GOTO 3080
1990 IF LEN(E$)=0 THEN RETURN :GOSUB 2000:E=E-1:IF E<0 OR E>5 THEN E=5:RETURN
2000 E=0:FOR Q=1 TO LEN(E$)
2020 E=E+( ASC(E$(Q,Q))-176)*10^( LEN(E$)-Q)
2035 NEXT Q:RETURN
3000 KK=0:VV=0
3005 J=0:K=0:A=0:X=0:Y=0:W=0:I=0:M=0:N=0:Q=0:P=0:LL=5
3010 TEXT :CALL -936:VTAB 4:TAB 14:PRINT "*** BREAKOUT ***":PRINT :PRINT " THE OBJECT IS TO DESTROY ALL THE BRICKS":
3020 DIM A$(15),B$(10):PRINT :INPUT "HI, WHAT'S YOUR NAME? ",A$:A=1:B=13:C=9:D=6:E=15:IF LEN(A$)=0 THEN A$="ACE":GR
3025 DIM QQ(2),E$(2):F=15:LL=5:PRINT "STANDARD COLORS, ";A$;
3030 INPUT "? ",B$:IF LEN(B$)=0 THEN 3060:IF B$(1,1)#"N" THEN 3060:FOR I=0 TO 39:COLOR= I/2*(I<32):VLIN 0,39 AT I
3040 NEXT I: POKE 34,20:PRINT :PRINT :PRINT :FOR I=0 TO 15:VTAB 21+I MOD 2:TAB I+I+1:PRINT I;:NEXT I: POKE 34,22:VTAB 24:PRINT :PRINT "BACKGROUND";
3045 E=A:GOSUB 170:A=E:PRINT "EVEN BRICK";:E=B:GOSUB 170:B=E:PRINT "ODD BRICK";:E=C:GOSUB 170:C=E
3050 PRINT "PADDLE";:E=D:GOSUB 170:D=E:PRINT "BALL";:E=F:GOSUB 170:F=E
3060 POKE 34,20:COLOR= A:FOR I=0 TO 39:VLIN 0,39 AT I:NEXT I:FOR I=20 TO 34 STEP 2:TAB I+1:PRINT I/2-9;:COLOR= B
3065 VLIN 0,39 AT I:COLOR= C:FOR J=I MOD 4 TO 39 STEP 4
3070 VLIN J,J+1 AT I:NEXT J,I:TAB 1:PRINT "SCORE = 0":PRINT :PRINT : POKE 34,21:S=0:P=S:L=S:X=19:Y=19:L=6
3075 INPUT "WHAT PADDLE SIZE (1 TO 6) ?",E$:IF LEN(E$)=0 THEN E$="6":GOSUB 2000:LL=E-1
3076 IF LL>5 THEN LL=5
3080 COLOR= A:PLOT X,Y/3:X=19:Y= RND (120):V=-1:W= RND (5)-2:L=L-1:IF L<1 THEN 510:TAB 6:IF L>1 THEN PRINT L;" BALLS LEFT"
3085 H= RND (3)+2:OD= RND (4)+3+H
3090 IF L=1 THEN PRINT "LAST BALL, ";A$:PRINT :FOR I=1 TO 100:GOSUB 50:NEXT I:M=1:N=0:GOTO 100
4001 REM 3/2/78
4002 REM IN THIS VERSION,WHEN PUTTING IN YOUR OWN COLORS, JUST HIT RETURN KEY FOR ANY COLORS YOU DO NOT WISH TO CHANGE
4003 REM PADDLE WILL DISPLAY PROPER"ENGLISH" REGARDLESS OF PADDLE SIZE
4004 REM THERE ARE 3 SPEED INCREMENTS WHICH CUT IN AT A RANDOM TIME
5000 REM MODIFIED BY BRUCE TOGNAZZINI,C/0 CARR ELECTRONICS CORP.,5811 GEARY BLVD.,SAN FRANCISCO,CA., 94121 PHONE (415)668-6800